Altid til tiden med DS1307 og DS3231 REAL tidsur-modulerne

Placeret på 2016-07-16

REAL

REAL tidsurserien indeholder mange forskellige typenumre, alle med sammenlignelig funktionalitet. I denne serie er kun 2 versioner 'mainstream', nemlig DS1307 og DS3231. Disse chips har både mulighed for at tilslutte et batteri og har en sqw output pin, hvormed controlleren kan modtage en clock puls på (1Hz, 1.024kHz, 4.096kHz, 8.192kHz). Begge IC'er har også et One-Wire interface, som gør det muligt at forbinde dem over I²henvende sig til C.

DS1302 Real Time Clock Module - SPIDS1302 Real Time Clock Module har et SPI-interface, hvorigennem det kan fortælle tiden. På lager € 1,95

REAL DS3231REAL med DS3231-chippen. Dette modul sikrer, at Arduino kender det nøjagtige tidspunkt til enhver tid. Ved at forbinde Arduino til 'sqw'-stiften er det muligt at generere et interrupt hvert sekund, hvormed sensorværdier eller et display kan adresseres. På lager € 4,10

Tilslutning af RTC-modulet til Arduino UNO

RTC-modulerne kommer i forskellige former og størrelser, men forbindelsen til Arduino er den samme for alle moduler. Modulet skal under alle omstændigheder strømforsynes med 5V, desuden skal I2C-interfacet forbindes til SDA (Serial data) SCL (Serial clock) benene på Arduino (disse er ben A4 og A5 på Arduino UNO). Ydermere kan SQW-udgangen forbindes til en hvilken som helst pin på Arduino for at modtage en clock-impuls fra RTC.

DS1307 tilslutning Arduino UNO

BC kode

De numeriske værdier i RTC-chippene er gemt i BCD-format. BCD-kode er lettere at bruge end decimaltal på hardwareniveau, men disse koder er ikke særlig nyttige i software. Numrene til og fra chippen skal derfor kodes og afkodes, så controlleren og RTC forstår hinanden.

// Convert decimal to BCD
byte decToBcd(byte val)
{
  return( (val/10*16) + (val%10) );
}
//Convert BCD to decimal
byte bcdToDec(byte val)
{
  return( (val/16*10) + (val%16) );
}

Skriv den aktuelle tid til RTC

Tiden skal kun skrives til RTC én gang, når den er tilsluttet batteriet. RTC'en holder selv tiden og fortsætter med at tælle, selv når den ikke er forbundet til controlleren.

#include "Wire.h"
#define DS3231_I2C_ADDRESS 0x68

void setDS3231time(
    byte second, 
    byte minute, 
    byte hour, 
    byte dayOfWeek, 
    byte dayOfMonth, 
    byte month, 
    byte year)
{
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  
  //set next input to start at the seconds register
  Wire.write(0); 
  
  //set seconds
  Wire.write(decToBcd(second)); 
  //set minutes
  Wire.write(decToBcd(minute)); 
  //set hours
  Wire.write(decToBcd(hour)); 
  //set day of week (1=Sunday, 7=Saturday)
  Wire.write(decToBcd(dayOfWeek));  
  //set date (1 to 31)
  Wire.write(decToBcd(dayOfMonth)); 
  //set month
  Wire.write(decToBcd(month));
  //set year 20(0 to 99)
  Wire.write(decToBcd(year)); 
    
  Wire.endTransmission();
}

Harddisk ur

De tijd van de RTC lezen

#include "Wire.h"
#define DS3231_I2C_ADDRESS 0x68

void readDS3231time(
    byte *second,
	byte *minute,
	byte *hour,
	byte *dayOfWeek,
	byte *dayOfMonth,
	byte *month,
	byte *year)
{
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  //set DS3231 register pointer to 00h
  Wire.write(0); 
  Wire.endTransmission();
      
  //request seven bytes of data from DS3231
  Wire.requestFrom(DS3231_I2C_ADDRESS, 7);
  *second = bcdToDec(Wire.read() & 0x7f);
  *minute = bcdToDec(Wire.read());
  *hour = bcdToDec(Wire.read() & 0x3f);
  *dayOfWeek = bcdToDec(Wire.read());
  *dayOfMonth = bcdToDec(Wire.read());
  *month = bcdToDec(Wire.read());
  *year = bcdToDec(Wire.read());
}

Vis tiden

Med disse funktioner sammen kan tiden bestemmes af Arduino . Med funktionen nedenfor skrives disse data til den serielle monitor, men mulighederne for at vise tiden er uendelige.

void setup()
{
  Wire.begin();
  Serial.begin(9600);
  
  //set the initial time (only once, not every startup)
  //seconds, minutes, hours, dayofweek, day, month, year
  //11:00:00, Saturday, 2016-07-16
  setDS3231time(00,00,11,7,16,7,16);
}

void displayTime()
{
  byte second, minute, hour; 
  byte dayOfWeek, dayOfMonth, month, year;
  
  //retrieve data
  readDS3231time(&second, &minute, &hour, &dayOfWeek, 				     &dayOfMonth, &month, &year);
    
  //Hour
  Serial.print(hour, DEC);
  Serial.print(":");
  //Minute (+0 if needed)
  if (minute<10)
  {
    Serial.print("0");
  }
  Serial.print(minute, DEC);
  Serial.print(":");
  //Second (+0 if needed)
  if (second<10)
  {
    Serial.print("0");
  }
  Serial.print(second, DEC);
  Serial.print(" ");
    
  //Day
  Serial.print(dayOfMonth, DEC);
  Serial.print("/");
  //Month
  Serial.print(month, DEC);
  Serial.print("/");
  //Year
  Serial.print(year, DEC);
}


void loop()
{
  displayTime(); 
  delay(1000);
}

SQW frequentie instellen

#include "Wire.h"
#define DS3231_I2C_ADDRESS 0x68

void setup()
{
  Wire.begin();
  Serial.begin(9600);
  
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  
  //move pointer to SQW address
  Wire.write(0x07); 
 
  //set output clock speed
  //0x00 = Off
  //0x10 = 1Hz
  //0x11 = 4.096Hz
  //0x12 = 8.192Hz
  //0x13 = 32.768Hz
  Wire.write(0x10);
 
  Wire.endTransmission();  
}

Med denne kode kan der bygges et komplet ur, som kan vise tiden. Dette kan gøres på et 7-segments display, som et analogt ur, med røgsignaler eller det kan endda tales op, når det bliver bedt om det. Derudover kan tiden også bruges i hjemmeautomatik / hjemmeautomatik, kaffemaskinen tænder klokken 8 om morgenen, mikroovnen klokken 17.15 om aftenen og gardinerne lukker klokken 19.01.05. Alt er muligt.

Sendt af Robin Blok Internet side Jeg interesserer mig for elektronik, programmering og især kombinationen af begge dele. Til Opencircuit skriver jeg blogs, hvor jeg forklarer, hvordan elektronik og moduler fungerer.