Arduino Uno som 74HC4051 (MUX/DEMUX) tester

Placeret på 2019-10-04

74HC4051 test

74HC4051 er en multiplekser/demultiplekser IC. For at teste dette kan Arduino Uno bruges med to 74HC4051 IC'er. Den første IC fungerer som en multiplekser, den anden som en demultiplekser.

pinout

Pin	Etiket	Fungere
1	A4	Kanal ind/ud
2	A6	Kanal ind/ud
3	A	Fælles ind/ud
4	A7	Kanal ind/ud
5	A5	Kanal ind/ud
6	~E	Aktiver (negativ)
7	Kvæg	Negativ strømforsyning
8	GND	Jord (0V)
9	Vcc	Strømforsyning (5Vdc)
10	A2	Kanal ind/ud
11	A1	Kanal ind/ud
12	A0	Kanal ind/ud
13	A3	Kanal ind/ud
14	S0	Adresselinje bit 0
15	S1	Adresselinje bit 1
16	S2	Adresselinje bit 2

Digital test

Selvom 74HC4051 er en analog MUX/DEMUX, kan den ikke testes analogt med Arduino Uno, da den ikke har nogen analoge udgange (DAC). Senere i denne artikel er det beskrevet, hvordan dette kan opnås med et DAC breakout board. For at teste digitalt er det kun nødvendigt med Arduino kortet og 2 IC'er.

Forbinde

Indstil pin 16 (Vcc) på begge IC'er til 5VDC; ben 8 (GND) ved 0V.

Tilslut ben 6 (~E) og 7 (Vee) på begge IC'er til GND også.

Tilslut følgende ben på begge IC'er: 1,2,4,5,15,16,13,12 (A0..A7).

Tilslut ben 11 (S0) på begge IC'er til Arduino -kortet på A0.

Tilslut pin 12 (S1) på begge IC'er til Arduino kortet på A1.

Tilslut ben 13 (S2) på begge IC'er til Arduino -kortet på A2.

Fra IC 1 skal du forbinde ben 3 (A) til Arduino kortet på A4.

Fra IC 2 skal du forbinde ben 3 (A) til Arduino kortet på A5.

Arduino kode

Brug følgende kode til Arduino

Test 74HC4051 MUX/DEMUX met Arduino Uno

/****************************************************************
      Configuratie
****************************************************************/
#define pinS0   A0 // Address select 0
#define pinS1   A1 // Address select 1
#define pinS2   A2 // Address select 2
#define pinA_ic1  A4    // A pin on IC1
#define pinA_ic2  A5    // A pin on IC2
/*****   EINDE CONFIGUTATIE    *****/

// Poll timer
unsigned long lastPoll;

/****************************************************************
      SETUP
****************************************************************/
void setup()
{
  Serial.begin(115200);
  while (!Serial) {
    ; // Wacht op seriele monitor
  }
  Serial.println("--- Seriele monitor gestart ---");

  // Configureer pinnen als uitgangen
  pinMode(pinS0, OUTPUT);
  pinMode(pinS1, OUTPUT);
  pinMode(pinS2, OUTPUT);
  pinMode(pinA_ic1, OUTPUT);
  // Configureer pinnen als ingangen
  pinMode(pinA_ic2, INPUT);

  lastPoll = millis();
}

/****************************************************************
      LOOP
****************************************************************/
void loop()
{
  static byte byteCounter = 0;
  static bool writeBit;
  static bool readBit;
  String testResult;

  // Genereer willekeurig true of false
  writeBit = bool(random(0, 2));

  // Elke 500ms
  if (millis() - lastPoll >= 500)
  {
    // Selecteer adres
    selectAddress(byteCounter);

    // Schrijf bit naar IC 1
    digitalWrite(pinA_ic1, writeBit);

    // Lees bit van IC 2
    readBit = digitalRead(pinA_ic2);

    if (writeBit == readBit) {
      testResult = " -> OK";
    }
    else {
      testResult = " -> NIET OK";
    }
    

    // In de seriële monitor moet bit schrijf = bit lees
    Serial.print("Op adres " );
    Serial.print(byteCounter, BIN);
    Serial.print(" is schrijf (IC 1) vs lees (IC 2): " );
    Serial.print(writeBit);
    Serial.print(" / ");
    Serial.print(readBit);
    Serial.print(testResult);
    Serial.println();

    // Selecteer volgend adres 
    byteCounter++;
    if (byteCounter > 7) {
      byteCounter = 0;  // Reset counter at 1000 (count 0000 to 0111)
    }
    lastPoll = millis();
  }
}

/****************************************************************
      Zet de Sx pinnen om het gewenste adres te selecteren
****************************************************************/
void selectAddress(byte address) {
  // Lees adres bits
  bool S0 = bool(address >> 0 & 0x01); // Shift rechts en maskeer met 0x01
  bool S1 = bool(address >> 1 & 0x01);
  bool S2 = bool(address >> 2 & 0x01);

  // Zet adres lijnen correct
  digitalWrite(pinS0, S0);
  digitalWrite(pinS1, S1);
  digitalWrite(pinS2, S2);
}
//EINDE

Resultatet er noget i denne genre:

Op adres 0 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 1 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 10 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 11 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 100 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 101 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 110 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 111 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 0 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 1 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 10 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 11 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK

Komponenter

Komponenterne til denne test:

Komponentliste

74HC4051 multiplexer - 5 stk Udsolgt (sælges pr. 5) € 3,75 Brødbræt 400 point - hvid Udsolgt € 1,95 Herre-Han jumper sæt 65 stk På lager € 3,05 i alt € 8,75

På samme måde kan du teste versionen på breakout boardet

SparkFun Multiplexer Breakout - 8-kanals (74HC4051)Frigør det fulde potentiale af 74HC4051 med Sparkfun Multiplexer Breakout. Omdan fire I/O-ben til otte valgbare signaler, velegnet til en række applikationer. Nem at bruge, pålidelig og alsidig for både hobbyfolk og professionelle. På lager € 4,25

Analog test

For at teste analog skal du bruge en DAC. Arduino Uno har ikke dette som standard, men ved hjælp af " Adafruit MCP4725 (12bit DAC)" breakout board kan du muligvis opnå dette.

MCP4725 Breakout Board - 12-bit DAC m/I2C InterfaceDin mikrocontroller har sikkert en ADC (analog -> digital konverter), men har den en DAC (digital -> analog konverter)??? Nu kan det! Dette breakout board har den brugervenlige MCP4725 12-bit DAC. Styr den via I2C og send den den værdi, du vil have den til at udlæse, og VOUT-stiften vil have den. Leveret i 10 til 30 dage € 5,90

Forbinde

Tilslutningen skal derefter justeres:
Sæt ben 3 (A) på IC 1 på udgangen af MCP4725 (VOU) (i stedet for på A5)
Sæt ben 3 (A) på IC 2 på ben A3 på Arduino -kortet (i stedet for på A4).
Ben A4 (SCA) og A5 (SCL) på Arduino kortet skal forbindes til SDA og SCL på MCP4725.
Tilslut også VDD og GND på MCP4725-kortet til henholdsvis 5V og GND.
Tilslut pin A0 på MCP4725 til GND for at vælge I2C-adresse 0x62.
(Alternativt: Vælg A0 ved 5V på adressen 0x63.)

Adafruit biblioteker

For at styre Adafruit MCP4725 DAC, anbefales det at downloade det tilsvarende bibliotek fra Adafruit .
Du kan finde disse på Github.

Koden til den analoge test er så som følger:

Test 74HC4051 MUX/DEMUX met Arduino Uno en DAC

// Voeg MCP4725 DAC bibliotheek toe
#include <Wire.h>               // I2C library
#include >Adafruit_MCP4725.h>   // Adafruit library for MCP4725 (DAC)
Adafruit_MCP4725 dac;

/****************************************************************
      Configuratie
****************************************************************/
#define pinS0   A0 // Address select 0
#define pinS1   A1 // Address select 1
#define pinS2   A2 // Address select 2
#define pinA_ic2  A3    // A pin on IC2
/*****   EINDE CONFIGUTATIE    *****/

// Poll timer
unsigned long lastPoll;

/****************************************************************
      SETUP
****************************************************************/
void setup()
{
  Serial.begin(115200);
  while (!Serial) {
    ; // Wacht op seriele monitor
  }
  Serial.println("--- Seriele monitor gestart ---");

  // Configureer pinnen als uitgangen
  pinMode(pinS0, OUTPUT);
  pinMode(pinS1, OUTPUT);
  pinMode(pinS2, OUTPUT);

  dac.begin(0x62);  // MCP4725, pin A0 ligt op GND
  // dac.begin(0x63);  // MCP4725, pin A0 ligt op 5V

  lastPoll = millis();
}

/****************************************************************
      LOOP
****************************************************************/
void loop()
{
  static byte byteCounter = 0;
  uint16_t writeChannel; // 12 bit (0-4095)
  uint16_t readChannel;  // 10 bit (0-1023)
  String testResult;

  // Genereer willekeurige analoge uitgang waarde
  writeChannel = random(0, 4096); // random 0-4095 (!)

  // Elke 500ms
  if (millis() - lastPoll >= 500)
  {
    // Selecteer adres
    selectAddress(byteCounter);

    // Schrijf naar DAC
    dac.setVoltage(writeChannel, false);

    // Lees analoge waarde van analoge ingang op Arduino
    readChannel = analogRead(pinA_ic2);

    // Converteer waarden naar volt
    writeChannel = map(writeChannel, 0, 4095, 0, 500);
    readChannel = map(readChannel, 0, 1023, 0, 500);

    // Zijn beide waarden gelijk ?
    if (writeChannel == readChannel) {
      testResult = " -> OK";
    }
    else {
      testResult = " -> NIET OK";
    }

    // In de seriële monitor moet schrijf waarde = lees waarde
    Serial.print("Op adres " );
    Serial.print(byteCounter, BIN);
    Serial.print(" is schrijf (IC 1) vs lees (IC 2): " );
    Serial.print(float(writeChannel)/100);
    Serial.print(" / ");
    Serial.print(float(readChannel)/100);
    Serial.print(testResult);
    Serial.println();

    // Selecteer volgend adres 
    byteCounter++;
    if (byteCounter > 7) {
      byteCounter = 0;  // Reset counter at 1000 (count 0000 to 0111)
    }
    lastPoll = millis();
  }
}

/****************************************************************
      Set the Sx pins to select proper address
****************************************************************/
void selectAddress(byte address) {
  // Lees adres bits
  bool S0 = bool(address >> 0 & 0x01); // Shift rechts en maskeer met 0x01
  bool S1 = bool(address >> 1 & 0x01);
  bool S2 = bool(address >> 2 & 0x01);

  // Zet adres lijnen correct
  digitalWrite(pinS0, S0);
  digitalWrite(pinS1, S1);
  digitalWrite(pinS2, S2);
}
//EINDE

Resultatet på den serielle monitor er i denne genre:

Op adres 10 is schrijf (IC 1) vs lees (IC 2): 3.40 / 3.40 -> OK
Op adres 11 is schrijf (IC 1) vs lees (IC 2): 4.21 / 4.21 -> OK
Op adres 100 is schrijf (IC 1) vs lees (IC 2): 0.08 / 0.08 -> OK
Op adres 101 is schrijf (IC 1) vs lees (IC 2): 1.54 / 1.54 -> OK
Op adres 110 is schrijf (IC 1) vs lees (IC 2): 1.53 / 1.53 -> OK
Op adres 111 is schrijf (IC 1) vs lees (IC 2): 4.02 / 4.02 -> OK
Op adres 0 is schrijf (IC 1) vs lees (IC 2): 0.82 / 0.82 -> OK
Op adres 1 is schrijf (IC 1) vs lees (IC 2): 0.93 / 0.93 -> OK
Op adres 10 is schrijf (IC 1) vs lees (IC 2): 3.72 / 3.72 -> OK
Op adres 11 is schrijf (IC 1) vs lees (IC 2): 1.35 / 1.35 -> OK
Op adres 100 is schrijf (IC 1) vs lees (IC 2): 2.64 / 2.64 -> OK
Op adres 101 is schrijf (IC 1) vs lees (IC 2): 1.29 / 1.29 -> OK
Op adres 110 is schrijf (IC 1) vs lees (IC 2): 2.89 / 2.88 -> NIET OK
Op adres 111 is schrijf (IC 1) vs lees (IC 2): 3.54 / 3.54 -> OK
Op adres 0 is schrijf (IC 1) vs lees (IC 2): 4.24 / 4.24 -> OK
Op adres 1 is schrijf (IC 1) vs lees (IC 2): 1.51 / 1.51 -> OK
Op adres 10 is schrijf (IC 1) vs lees (IC 2): 4.20 / 4.20 -> OK

Der vil af og til være "fejl" på grund af afrundinger og unøjagtigheder. For eksempel kan du se, at 2,89V ikke er lig med 2,88V. Men i kombination med alle andre vellykkede resultater kan du gå ud fra, at MUX/DEMUX fungerer perfekt.

Sendt af Arashi Internet side

Arduino Uno som 74HC4051 (MUX/DEMUX) tester

74HC4051 test

pinout

Digital test

Forbinde

Arduino kode

Test 74HC4051 MUX/DEMUX met Arduino Uno

Komponenter

Komponentliste

Analog test

Forbinde

Adafruit biblioteker

Test 74HC4051 MUX/DEMUX met Arduino Uno en DAC

Kommentarer