Byg din egen Bluetooth-nyhedsticker

Placeret på 2017-11-13

Eksempel på nyhedsticker

Forsyninger

Opencircuit Arduino Uno R3 - klon På lager Eller en Arduino Nano € 11,75 Opencircuit MAX7219 4x Dot matrix modul På lager Dette er skærmen, du har brug for mindst 1, 2 er endnu bedre! € 10,60 Opencircuit HC-06 Bluetooth modul med adapter - klon På lager Dette er HC-06 Bluetooth-slaven, du skal bruge 1 € 8,85 Opencircuit 5,6KΩ Metalfilmmodstand 1/4W - 100 stk Leveret i 14 til 30 dage Spændingsdeleren til Bluetooth-modulet € 1,35 Opencircuit 10KΩ Metalfilmmodstand 1/4W - 10 stk På lager Spændingsdeleren til Bluetooth-modulet € 1,80 Ikke længere tilgængelig For ekstra strøm kan USB ikke levere nok Opencircuit DC-stik indbygget 5,5mm x 2,1mm - 5 stk På lager € 2,60 i alt € 36,95

Skemaet:

Skemaet viser, hvordan alt skal hænge sammen. Hvis du allerede får en snurrende fornemmelse af alle de ledninger, skal du ikke se for meget på helheden, men prøv at overveje og forbinde modulerne én efter én. Du vil se, at det ikke er så slemt.

Skemaet viser kun et firedobbelt dot matrix LED-modul, i virkeligheden kan du koble to sammen til en dobbelt bredde!

Opslagstavle forbindelsesdiagram

Bluetooth-modulet kræver lidt ekstra opmærksomhed. Bluetooth kommunikationssignalerne (TX og RX) arbejder ved 3,3 volt, mens Arduino arbejder med 5 volt. De to modstande vil reducere de 5 volt fra Arduino til omkring 3,3 volt.

Ernæringen:
Du kan se, at der bruges en 5 volt strømforsyning. Du skal. En Arduino tilsluttet USB kan ikke levere nok strøm til at drive LED-matricen, især med en dobbelt matrix.

Arduino bibliotek og skitse:

Arduino skitsen bruger to eksterne biblioteker, for at installere disse, søg efter MD_MAX72xx i biblioteksadministratoren. Installer derefter MD_Max72xx og MD_Parola

Ticker USB Arduino bibliotek

Indstil det rigtige modul:
Efter installation af bibliotekerne skal vi fortælle MD_Max72xx-biblioteket, hvilket led-matrix-modul vi bruger.

Find filen på din harddisk: MD_MAX72xx.h
(sandsynligvis i mappen C:\Users\dit navn\Documents\ Arduino \libraries\MD_MAX72XX\src\)

//Op regel 214, zie je staan:   
#define   USE_PAROLA_HW   1, verander die 1 in 0

//Op regel 237 zie je staan: 
#define   USE_FC16_HW   0,   verander die 0 in 1.

Arduino skitsen:

Så kan vi nu indlæse skitsen.
Kopier skitsen og indsæt koden i Arduino softwaren, vælg den korrekte com-port og skriv Arduino og tryk upload!

#include <MD_Parola.h>
#include <MD_MAX72xx.h>
#include <SPI.h>
#include <SoftwareSerial.h>
#include <EEPROM.h>
#define MAX_DEVICES 8
#define CLK_PIN   13
#define DATA_PIN  11
#define CS_PIN    10

// Use softserial for the bluetooth module
SoftwareSerial mySerial(2, 3);

// HARDWARE SPI
MD_Parola LK = MD_Parola(CS_PIN, MAX_DEVICES);

uint8_t scrollSpeed = 30;    // default frame delay value
textEffect_t scrollEffect = PA_SCROLL_LEFT;
textPosition_t scrollAlign = PA_LEFT;
uint16_t scrollPause = 2000; // in milliseconds

// Global message buffers shared by Serial and Scrolling functions
#define  BUF_SIZE  75
char curMessage[BUF_SIZE];
char newMessage[BUF_SIZE];
bool newMessageAvailable = false;

void setup()
{
  // Enable the next line to clear the message from eeprom.
  // EEPROM.write(0,1);
  
  mySerial.begin(9600); 
  delay(500);
  
  // The next line configures the BT-04 (BT-06) Module to NOT report connection status. 
  mySerial.write("\r\nAT+ENABLEIND0\r\n"); 
  delay(100);
  ClearRXbuffer();
  
  // change the name of the BT-04 (BT-06) device, this will not work for HC-06
  mySerial.write("AT+NAMELichtkrant01\r\n"); 
  delay(100);
  ClearRXbuffer();
  
  LK.begin();
  LK.displayClear();
  LK.displaySuspend(false);
  LK.displayText(curMessage, scrollAlign, scrollSpeed, scrollPause, scrollEffect, scrollEffect);  

  // Get the last message from EEPROM
  getMessageFromEeprom();
}


void loop()
{  
  readSerial();
  if (LK.displayAnimate())
  {
    if (newMessageAvailable)
    {
      strcpy(curMessage, newMessage);
      newMessageAvailable = false;
      storeMessageInEeprom();
    }
    LK.displayReset();
  }
}


  
void readSerial(void) {
  static char *cp = newMessage;
  while (mySerial.available())  
  {
    *cp = (char)mySerial.read();
    if ( (*cp == '\r') || (*cp == '\n') || (cp - newMessage >= BUF_SIZE-2)) // end of message character or full buffer
    {
      *cp = '\0'; // end the string   
      cp = newMessage;
      newMessageAvailable = true;
      mySerial.print("Nieuwe Boodschap = ");
      mySerial.println(newMessage);
      ClearRXbuffer();
    }
    else  // move char pointer to next position
      cp++;
  }
}


void storeMessageInEeprom(){
  // Store the message in EEPROM
  EEPROM.write(0,251);
  int i=0;
  char c=curMessage[i];
  while (c !=0){
    EEPROM.write(i+1,c);
    i++;
    c=curMessage[i];
    }
    EEPROM.write(i+1,0);
}

void getMessageFromEeprom(){
  if (EEPROM.read(0)!=251){
    strcpy(curMessage, "Hello! Please Send new message over bluetooth");
    newMessage[0] = '\0';
    } else {      
      int i=0;
      char c = EEPROM.read(i+1);
      while (c!=0){
        curMessage[i++]=c;
        c = EEPROM.read(i+1);
        }
        curMessage[i] = '\0';
        newMessageAvailable=false;         
    }
}

void ClearRXbuffer(){
  while (mySerial.available()){
    char c=mySerial.read(); 
    delay(5);
    } 
}

Hvis alt er godt (og hvorfor ikke?) vil du nu se beskeden "Hej, send venligst en ny besked over bluetooth". Så det er på høje tid at installere Android-appen på din telefon og sende en ny besked via Bluetooth!

Android-appen:

For at ændre teksten på nyhedstickeren har vi brug for et Bluetooth-terminalprogram, for eksempel den serielle Bluetooth-terminal fra Kai Morich, via App butik.

SerielBluetoothTerminal

Betjeningen af appen er ret selvforklarende, men i videoen viser jeg det trin for trin.

bluetooth terminal

OBS: Apples iOS kan ikke oprette forbindelse til det brugte bluetooth-modul, så dette virker kun med Android-enheder.

se videoen

Er der stadig uklarheder? Du kan se nærmere på alt i denne video.

Sendt af Bart Venneker Internet side | Youtube Bart Venneker er elektronikhobbyist og laver undervisningsvideoer om elektronik, Arduino og 3d-printere.

Kommentarer

Ad Laat

Desværre kan justeringerne ikke findes på biblioteket, hvilket betyder, at tickeren ikke virker, hvilket er en skam! Kunne en anden version have været brugt? Hilsen Ad de Laat

Placeret på 19 november 2023

